Forum - message

Nouveau sujet | Remonter au début | Retour au sujet | Rechercher | S'identifier

Scripts ASP

Auteur: Nbre de scripts ASP ->
Date: 27-12-2002 11:27

Section de scripts ASP divers.

RAPPELS :
Si vous avez des questions sur les scripts, merci de passer par le forum général Amen (le 1er forum de la liste).

Pour ouvrir les liens proposés sans quitter le forum, clic droit sur le lien => ouvrir dans une nouvelle fenêtre.

Certains scripts sont proposés en pièces jointes.
:)

Répondre à ce message

Détection de composants

Auteur: Christophe [AMEN]
Date: 27-12-2002 11:39

Voici un script permettant de vérifier la présence d'un composant sur votre serveur Windows.

Sur serveur privé Virtuozzo Windows, vous pouvez installer vos propres composants à partir du bureau à distance.

Téléchargez l'archive ZIP en pièce jointe, décompressez et publiez le fichiers "composants.asp" sur votre serveur.

Appelez le script par l'url :

www.votre-domaine.com/composants.asp

Ou faire un copier-coller du script :

*******************************************

<% Option Explicit %>

<%

' COMPOSANTS PRESENTS PAR DEFAUT DANS IIS
' cette liste est non exaustive et modifiable
dim liste_objets(8)

liste_objets(0) = "aspSmartUpload.SmartUpload"
liste_objets(1) = "MSWC.AdRotator"
liste_objets(2) = "MSWC.BrowserType"
liste_objets(3) = "MSWC.Counters"
liste_objets(4) = "MSWC.NextLink"
liste_objets(5) = "MSWC.PermissionChecker"
liste_objets(6) = "MSWC.Status"
liste_objets(7) = "MSWC.Tools"
liste_objets(8) = "test.test"

' FIN COMPOSANTS PRESENTS PAR DEFAUT DANS IIS

function objet_installe(nom_objet)
' FONCTION DE TEST
' ENTREE : nom d'un composant
' SORTIE : vrai ou faux

On Error Resume Next ' pour récupérer le code d'erreur

' initialisation
objet_installe = False
Err = 0

dim xTestObj
Set xTestObj = Server.CreateObject(nom_objet) ' création d'une instance de l'objet
If Err=0 Then ' pas d'erreur
objet_installe = True
end if
Set xTestObj = Nothing
Err = 0
End Function
%>

<html>
<head>
<title>Tester la présence d'un composant</title>
</head>
<body>

<div align="center">Vérifiez
la présence de composants 
sur votre Serveur Privé Windows AMEN 
</div>
<form action="<%=request.ServerVariables("SCRIPT_NAME")%>" method="post">
<div align="center">
 
Saisir ici
le nom d'un composant 
et /ou cliquez sur "Tester" 
 
<input type="text" name="nom_objet" size="40" onFocus="this.select()" style="font-family: Verdana;font-size:12px;color:#000000;background-color:#CCCCCC" value="test.composant">
 
 
<input type="submit" value="Tester">
<input type="reset" value="Annuler">

</div>
</form>

<%
Dim nom_objet
nom_objet = trim(request.form("nom_objet")) ' récupération du nom du composant à tester

if nom_objet<>"" then
' test d'un composant en particulier dont le nom a été saisi

If not(objet_installe(nom_objet)) then%>
<%=nom_objet%> : Pas
installé (ou erreur de saisie sur le nom du composant) 
 
<%
Response.Write (" <hr width=""75%""> Exemple : ")
%>
<%else%>
<%=nom_objet%> : Installé 
 
<%
Response.Write (" <hr width=""75%""> Exemple : ")
%>
<%end if

' test des composants de la liste par défaut
dim i
for i=0 to UBound(liste_objets) ' parcours de la liste
if not(objet_installe(liste_objets(i))) then%>
<%=liste_objets(i)%> : Pas
installé (ou erreur de saisie sur le nom du composant) 
<%else%>
<%=liste_objets(i)%> : Installé 
<%end if
next
end if%>
</body>
</html>

************************************************

@+
Christophe

Répondre à ce message

Redirection d'alias de domaine sur serveur privé Windows

Auteur: Christophe [AMEN]
Date: 26-12-2003 16:01

Le serveur privé Windows n'est pas multi-domaines dans le sens où il n'est pas possible de définir, à partir de l'interface d'administration Sphera, dans quel répertoire doit pointer chaque domaine enregistré (ou alias).

Il est possible de créer des alias de domaine (voir le mode d'emploi) et chaque alias pointera dans le répertoire par défaut WWW.
Si vous souhaitez rediriger chaque domaine dans des répertoires différents, afin d'héberger plusieurs sites sur un même VDS, il faut donc utiliser un script ASP qui permettra de gérer les redirections.

Voici un exemple de script basique (vous pouvez en trouver d'autres en lançant une recherche sur Internet avec par exemple "ASP redirection répertoire").
Certains scripts peuvent être couplés avec une base de données.

Il suffit d'enregistrer ce script comme default.asp et de le publier dans le répertoire par défaut WWW avec votre propre paramétrage.

Dans l'exemple :
domaine.com est le domaine principal, il n'est pas redirigé mais il est possible de paramétrer également un répertoire de redirection.

domain2.com est un alias de domaine.
Il est redirigé sur le répertoire nommé domain2
domain2.com ou www.domain2.com affichera la page suivante :
domain2.com/domain2/default.asp

domain2.net est un autre alias de domaine.
Il est redirigé sur le répertoire nommé domain2net
domain2.net/domain2net/default.asp

'**************************************
' Name: Multi Domain Redirect
' Description:If you have multiple domai
' n names pointing to the same web site, t
' his code will allow you to redirect the
' user to a subdirectory based on the web
' address then type in the browser.
' By: Glenn C.
'
'This code is copyrighted and has ' limited warranties.Please see http://w
' ww.Planet-Source-Code.com/vb/scripts/Sho
' wCode.asp?txtCodeId=6349&lngWId=4 'for details.
'**************************************

<%@ Language=VBScript %>
<%
' Set up your variables
Dim sURL, sPath
' Get the domain name typed in the brows
' er.
sURL = Request.ServerVariables("HTTP_HOST")
' Get the rest of the path after the dom
' ain name.
sPath = Request.ServerVariables("PATH_INFO")
' Based on the domain name, redirect the
' user
' to the correct directory and attach th
' e rest
' of the path.
Select Case sURL
Case "www.domaine.com", "domaine.com"
' Ignore...this is the current site.
Case "www.domain2.com", "domain2.com"
' redirect To the "domain2" directory
Response.Redirect "domain2" & sPath
Case "www.domain2.net", "domain2.net"
' redirect to the "domain2net" directory
'
Response.Redirect "domain2net" & sPath
End Select
%>

Voir le site dédié à ce script :

http://www.planet-source-code.com/vb/scripts/ShowCode.asp?lngWId=4&txtCodeId=6349

Répondre à ce message

Envoyer un mail sans composant sur serveur Amen

Auteur: Christophe [AMEN]
Date: 20-06-2006 16:15

Script fonctionnant sur pack Webpro Windows et serveur privé Virtuozzo Windows :

Pour information, sur serveur privé Virtuozzo Windows, vous pouvez installer des composants ASP (via le bureau à distance)
.

Point 1 : Sur les packs ProWin, le SMTP fonctionne uniquement avec authentification, y compris si le mail envoyé l'est via un script ASP.

Point 2 : Pour utiliser un script ASP d'envoi de mail, il faut que le composant mail correspondant soit installé sur le serveur.

Le script proposé ci-dessous est compatible car il permet une authentification SMTP et il ne se sert d'aucun composant sur le serveur Amen, ce qui fait qu'il peut fonctionner même si la configuration de nos serveurs changent à ce niveau.
Et par la même occasion, cela "économise" donc des ressources sur nos serveurs car le composant utilisé (CDO) se trouve directement sur des serveurs mis à disposition par Microsoft.

Sur serveur privé Virtuozzo Windows, ce script fonctionne également très bien dans la mesure où MailEnable est correctement paramétré.

Il suffit d'adapter les lignes suivantes dans le script :

ligne 23 : .Item(cdoSMTPServer) = "DOMAINE OU IP DU SERVEUR"

ligne 27 : .Item(cdoSendUserName) = "LOGIN DU COMPTE MAIL LOCAL"

ligne 28 : .Item(cdoSendPassword) = "MOT DE PASSE DU COMPTE MAIL CI DESSUS"

ligne 38 à 41 : Bien sûr, cette partie peut être couplée à un formulaire afin de récupérer les données
.To = "ADRESSE MAIL DESTINATAIRE"
.From = "ADRESSE MAIL EXPEDITEUR"
.Subject = "SUJET DU MAIL"
.TextBody = "CONTENU DU MESSAGE A ENVOYER"

Voici le script complet (à enregistrer comme fichier .asp) :

<%
Const cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing"
Const cdoSendUsingPort = 2
Const cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
Const cdoSMTPServerPort = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
Const cdoSMTPConnectionTimeout = "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
Const cdoSMTPAuthenticate = "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
Const cdoBasic = 1
Const cdoSendUserName = "http://schemas.microsoft.com/cdo/configuration/sendusername"
Const cdoSendPassword = "http://schemas.microsoft.com/cdo/configuration/sendpassword"

Dim objConfig ' As CDO.Configuration
Dim objMessage ' As CDO.Message
Dim Fields ' As ADODB.Fields

' Get a handle on the config object and it's fields
Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields

' Set config fields we care about
With Fields
.Item(cdoSendUsingMethod) = cdoSendUsingPort
.Item(cdoSMTPServer) = "DOMAINE OU IP DU SERVEUR"
.Item(cdoSMTPServerPort) = 25
.Item(cdoSMTPConnectionTimeout) = 20
.Item(cdoSMTPAuthenticate) = cdoBasic
.Item(cdoSendUserName) = "LOGIN DU COMPTE MAIL LOCAL"
.Item(cdoSendPassword) = "MOT DE PASSE DU COMPTE MAIL CI DESSUS"

.Update
End With

Set objMessage = Server.CreateObject("CDO.Message")

Set objMessage.Configuration = objConfig

With objMessage
.To = "ADRESSE MAIL DESTINATAIRE"
.From = "ADRESSE MAIL EXPEDITEUR"
.Subject = "SUJET DU MAIL"
.TextBody = "CONTENU DU MESSAGE A ENVOYER"
.Send
End With

Set Fields = Nothing
Set objMessage = Nothing
Set objConfig = Nothing %>

Répondre à ce message

Liste des forums | Vue en arborescence

Nouveau sujet | Anciens sujets

Liste des forums